Gecko [ www.blackthorn-inc.com ]

Name	Size	Permission	Date
FindExt.t	2.62 KB	-r--r--r--	2014-12-27 11:49
args_assert.t	1.39 KB	-r--r--r--	2014-12-27 11:49
authors.t	462 B	-r--r--r--	2014-12-27 11:49
bincompat.t	446 B	-r--r--r--	2014-12-27 11:49
checkcase.t	1.17 KB	-r--r--r--	2014-12-27 11:49
checkcfgvar.t	1.36 KB	-r--r--r--	2014-12-27 11:49
cmp_version.t	486 B	-r--r--r--	2014-12-27 11:49
copyright.t	1.88 KB	-r--r--r--	2014-12-27 11:49
corelist.t	532 B	-r--r--r--	2015-01-28 21:08
customized.dat	3.13 KB	-r--r--r--	2015-01-31 22:00
customized.t	3.02 KB	-r--r--r--	2014-12-27 11:49
diag.t	23.62 KB	-r--r--r--	2015-01-15 22:12
dual-life.t	1.63 KB	-r--r--r--	2014-12-27 11:49
exec-bit.t	1.81 KB	-r--r--r--	2014-12-27 11:49
extrefs.t	3.32 KB	-r--r--r--	2014-12-27 11:49
filenames.t	1.9 KB	-r--r--r--	2014-12-27 11:49
globvar.t	1.82 KB	-r--r--r--	2014-12-27 11:49
known_pod_issues.dat	9.81 KB	-r--r--r--	2015-01-17 16:54
maintainers.t	884 B	-r--r--r--	2014-12-27 11:49
manifest.t	3.05 KB	-r--r--r--	2014-12-27 11:49
pending-author.t	1.75 KB	-r--r--r--	2014-12-27 11:49
perlfunc.t	1.39 KB	-r--r--r--	2014-12-27 11:49
pod_rules.t	1.04 KB	-r--r--r--	2014-12-27 11:49
podcheck.t	75.45 KB	-r--r--r--	2014-12-27 12:37
readme.t	2.22 KB	-r--r--r--	2014-12-27 11:49
regen.t	2.04 KB	-r--r--r--	2014-12-27 12:37
ss_dup.t	863 B	-r--r--r--	2014-12-27 11:49
test_bootstrap.t	2.42 KB	-r--r--r--	2014-12-27 11:49
utils.t	3.3 KB	-r--r--r--	2014-12-27 11:49

Rename

#!./perl -w

# Test that CUSTOMIZED files in Maintainers.pl have not been overwritten.

BEGIN {
        # This test script uses a slightly atypical invocation of the 'standard'
        # core testing setup stanza.
        # The existing porting tools which manage the Maintainers file all
        # expect to be run from the root
        # XXX that should be fixed

chdir '..' unless -d 't';
    @INC = qw(lib Porting t);
    require 'test.pl';
}

use strict;
use warnings;
use Digest;
use File::Spec;
use Maintainers qw[%Modules get_module_files get_module_pat];

sub filter_customized {
    my ($m, @files) = @_;

return @files
        unless my $customized = $Modules{$m}{CUSTOMIZED};

my ($pat) = map { qr/$_/ } join '|' => map {
        ref $_ ? $_ : qr/\b\Q$_\E$/
    } @{ $customized };

return grep { $_ =~ $pat } @files;
}

sub my_get_module_files {
    my $m = shift;
    return filter_customized $m => map { Maintainers::expand_glob($_) } get_module_pat($m);
}

my $TestCounter = 0;

my $digest_type = 'SHA-1';

my $original_dir = File::Spec->rel2abs(File::Spec->curdir);
my $data_dir = File::Spec->catdir('t', 'porting');
my $customised = File::Spec->catfile($data_dir, 'customized.dat');

my %customised;

my $regen = 0;

while (@ARGV && substr($ARGV[0], 0, 1) eq '-') {
    my $arg = shift @ARGV;

$arg =~ s/^--/-/; # Treat '--' the same as a single '-'
    if ($arg eq '-regen') {
        $regen = 1;
    }
    else {
        die <<EOF;
Unknown option '$arg'

Usage: $0 [ --regen ]\n"
    --regen    -> Regenerate the data file for $0

EOF
    }
}

my $data_fh;

if ( $regen ) {
  open $data_fh, '>:raw', $customised or die "Can't open $customised";
}
else {
  open $data_fh, '<:raw', $customised or die "Can't open $customised";
  while (<$data_fh>) {
    chomp;
    my ($module,$file,$sha) = split ' ';
    $customised{ $module }->{ $file } = $sha;
  }
  close $data_fh;
}

foreach my $module ( sort keys %Modules ) {
  next unless my $files = $Modules{ $module }{CUSTOMIZED};
  my @perl_files = my_get_module_files( $module );
  foreach my $file ( @perl_files ) {
    my $digest = Digest->new( $digest_type );
    {
      open my $fh, '<', $file or die "Can't open $file";
      binmode $fh;
      $digest->addfile( $fh );
      close $fh;
    }
    my $id = $digest->hexdigest;
    if ( $regen ) {
      print $data_fh join(' ', $module, $file, $id), "\n";
      next;
    }
    my $should_be = $customised{ $module }->{ $file };
    is( $id, $should_be, "SHA for $file matches stashed SHA" );
  }
}

if ( $regen ) {
  pass( "regenerated data file" );
  close $data_fh;
}

done_testing();

=pod

=head1 NAME

customized.t - Test that CUSTOMIZED files in Maintainers.pl have not been overwritten

=head1 SYNOPSIS

cd t
 ./perl -I../lib porting/customized.t --regen

=head1 DESCRIPTION

customized.t checks that files listed in C<Maintainers.pl> that have been C<CUSTOMIZED>
are not accidently overwritten by CPAN module updates.

=head1 OPTIONS

=over

=item C<--regen>

Use this command line option to regenerate the C<customized.dat> file.

=back

=cut